Finance & Accounting functions

Guides • Lambda • 18/09/2022

DEPR_ACC_SL

IAS 16 Property, Plant and Equipment

About

Shows the accumulated depreciation of an asset (based on its carrying amount and residual value), at the end of each period, according to the I.F.R.S. definition of how to straight line depreciate an asset.

Calls DAYS_PASSED.PCT.

Inputs:

depreciable_amount : The asset’s latest estimated carrying amount (at the start_date), less its latest estimated residual value (at the start_date)
useful_life_months : The assets latest estimated useful life (at the start_date), in ‘months’
start_date : The start date of depreciation calculations
eom_dates : Horizontal vector of month end dates
months_to_show : OPTIONAL - the number of months to show in the resulting depreciation vector (should be less than or equal to the length of the dates vector, eom_dates)

Code

M.S. Excel

DEPR_ACC_SL = LAMBDA(depreciable_amount, useful_life_months, start_date, eom_dates, [months_to_show],
    LET(
        useful_life_days, useful_life_months * (365.25 / 12),
        days_passed_pct, DAYS_PASSED.PCT(
            start_date,
            start_date + useful_life_days - 1,
            eom_dates
        ),
        accumulated_monthly_depreciation, days_passed_pct * depreciable_amount,
        TAKE(accumulated_monthly_depreciation, , months_to_show)
    )
);

Note:
The carrying amount is the amount at which an asset is recognised after deducting any accumulated depreciation (amortisation) and accumulated impairment losses thereon. The recoverable amount is the higher of an asset’s or cash generating unit fair value less costs of disposal and its value in use. If an asset’s carrying amount is considered to be less than its recoverable amount, it should be impaired.

Note:
The residual value of an asset is the estimated amount that an entity would currently obtain from disposal of the asset, after deducting the estimated costs of disposal, if the asset was already of the age and in the condition expected at the end of its useful life.