Finance & Accounting functions

DEFERRED

IFRS 15 - Revenue; & IFRS ##s - Expenses

About

Helps with showing Deferred Amounts in Finance & Accounting, in accordance with the I.F.R.S. Standards.

Recognition and De-Recognition dates are complex! They depend on:

  1. whether you are considering a Revenue or Expense
  2. whether the Contract is Cancellable or Non-Cancellable
  3. when amounts become Un-Conditionally due
  4. when the corresponding Invoice has been issued (then received or sent), and
  5. when / if Cash has been received or paid

So, the logic for these dates has been excluded from this function. (You’ll, for now, need to work them out separately, depending on what documents you have).

Calls DAYS_PASSED.PCT.

Inputs:

  • amount : Contract Amount
  • contract_start : Start Date of the Contract
  • contract_end : End Date of the Contract
  • eom_dates : Horizontal vector of month end dates
  • deferral_recog_date : Recognition Date
  • deferral_derecog_date : De-Recognition Date (usually set the same as contract_end)
  • deferral_needed : OPTIONAL - if a deferral is needed, set to ‘TRUE’; if not needed, set to ‘FALSE’. If blank, ‘TRUE’ is assumed

More Info:

NOTE: In the context of Revenue, this is sometimes also known as a CONTRACT LIABILITY.

Code

M.S. Excel 
DEFERRED = LAMBDA(amount, contract_start, contract_end, eom_dates, deferral_recog_date, deferral_derecog_date, [deferral_needed],
    LET(
        deferral, IF(
            (deferral_recog_date <= eom_dates) * (eom_dates < deferral_derecog_date),
                (1 - DAYS_PASSED.PCT(contract_start, contract_end, eom_dates)) * amount,
                0
        ) * --IF(ISOMITTED(deferral_needed), TRUE, deferral_needed),
        deferral
    )
);